media-video/bento4: add 1.6.0.641_p20240804

media-video/bento4/Manifest

@@ -1 +1,2 @@
 DIST bento4-1.6.0.641.tar.gz 5483983 BLAKE2B 8bec91edcba170917de5941d94fecbc2028d4503651e7863b5c6a5d24bbe442b7a5d53644770d3221c28c5a9f2a2620c04e836f748660a808e27e157db93b117 SHA512 ad92c561a16a830ac63b0fbff98bd14f732dd2e38416de937191b14c750e632c793e5256b92361d3ff8867f9fd1cf727756ba78cd0122af1b79d62532d2ca427
+DIST bento4-1.6.0.641_p20240804.tar.gz 5492006 BLAKE2B 2b7f606bcb2319b7c9fb3bb5a5152144bb54758b0d2c5ca4de66e30eb3ce30424e9d74d0b479d317e00b7048d6bcc694d6782bcbded97d9f5149927af5a54c8f SHA512 70583199e0bd864d6aecdc2ee47af142d661ad37663393bab57c3f4d6abb123a2b3915a88cb5a785bd2588439cfa7bef98ad8b8a874bb3538ba65e5ddc23deec

media-video/bento4/bento4-1.6.0.641.ebuild

@@ -3,7 +3,7 @@
 
 EAPI=8
 
-MY_PV="$(ver_cut 1-3)-$(ver_cut 4)"
+MY_PV="$(ver_rs 3 '-')"
 
 inherit cmake
 

media-video/bento4/bento4-1.6.0.641_p20240804.ebuild

@@ -0,0 +1,59 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PV="$(ver_rs 3 '-')"
+BENTO4_COMMIT_ID="3b809bd6622c2afdb391bcce1d982ecc4e3176e2"
+
+inherit cmake
+
+DESCRIPTION="Full-featured MP4 format, MPEG DASH, HLS, CMAF SDK and tools"
+HOMEPAGE="
+	https://www.bento4.com/
+	https://github.com/axiomatic-systems/Bento4
+"
+
+SRC_URI="
+	https://github.com/axiomatic-systems/Bento4/archive/${BENTO4_COMMIT_ID}.tar.gz
+		-> ${P}.tar.gz
+"
+S="${WORKDIR}/${PN^}-${BENTO4_COMMIT_ID}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="+apps"
+
+src_prepare() {
+	sed -i 's#ap4 STATIC#ap4 SHARED#g' CMakeLists.txt || die
+
+	sed -e 's#@BENTO4_VERSION@#'${MY_PV}'#g' \
+		-e 's#@LIBDIR@#'$(get_libdir)'#g' \
+		-e 's#@EPREFIX@#'"${EPREFIX}"/usr'#g' \
+		"${FILESDIR}"/bento4.pc.in > bento4.pc || die
+
+	# Avoid conflicts with media-libs/libmp4v2[utils]
+	for app in Mp4Info Mp4Extract; do
+		mv Source/C++/Apps/${app}/${app}.cpp Source/C++/Apps/${app}/${app}-${PN}.cpp || die
+		mv Source/C++/Apps/${app} Source/C++/Apps/${app}-${PN} || die
+	done
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_BUILD_RPATH=ON
+		-DBUILD_APPS=$(usex apps ON OFF)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins "${S}"/bento4.pc
+
+	cmake_src_install
+}