- Add fix for totem.

2025-12-06 22:32:37 +01:00 · 2015-05-03 14:25:06 +02:00
parent a9e9aaf986
commit de52f801cf
18 changed files with 879 additions and 0 deletions
--- a/media-plugins/grilo-plugins/grilo-plugins-0.2.13-r1.ebuild
+++ b/media-plugins/grilo-plugins/grilo-plugins-0.2.13-r1.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/grilo-plugins/grilo-plugins-0.2.13.ebuild,v 1.6 2015/02/23 11:59:50 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no" # --enable-debug only changes CFLAGS
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="A framework for easy media discovery and browsing"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.2"
+KEYWORDS="amd64 ~ppc ~ppc64 x86"
+IUSE="daap +dvd flickr freebox gnome-online-accounts lua pocket thetvdb tracker upnp-av +vimeo +youtube"
+
+RDEPEND="
+	>=dev-libs/glib-2.36:2
+	>=media-libs/grilo-0.2.11:${SLOT}[network,playlist]
+	>=media-libs/libmediaart-0.1
+	>=dev-libs/gom-0.2.1
+
+	dev-libs/gmime:2.6
+	dev-libs/json-glib
+	dev-libs/libxml2:2
+	dev-db/sqlite:3
+
+	daap? ( >=net-libs/libdmapsharing-2.9.12:3.0 )
+	dvd? ( >=dev-libs/totem-pl-parser-3.4.1 )
+	flickr? ( net-libs/liboauth )
+	freebox? ( net-dns/avahi )
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.7.1 )
+	lua? (
+		>=dev-lang/lua-5.2
+		app-arch/libarchive )
+	pocket? (
+		>=net-libs/gnome-online-accounts-3.11.4
+		>=net-libs/rest-0.7.90
+		>=dev-libs/totem-pl-parser-3.4.1 )
+	thetvdb? (
+		app-arch/libarchive
+		dev-libs/libxml2 )
+	tracker? ( >=app-misc/tracker-0.10.5:= )
+	youtube? (
+		>=dev-libs/libgdata-0.9.1:=
+		dev-libs/totem-pl-parser )
+	upnp-av? ( net-libs/libsoup )
+	vimeo? (
+		dev-libs/totem-pl-parser )
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.5
+	app-text/yelp-tools
+	>=dev-util/intltool-0.40.0
+	virtual/pkgconfig
+"
+
+src_prepare() {
+
+    epatch "${FILESDIR}/${P}-0001-fix-thumbnail-url-not-getting-saved.patch"
+    epatch "${FILESDIR}/${P}-0002-fix-updating-bookmarks.patch"
+    epatch "${FILESDIR}/${P}-0003-tracker-correctly-set-title-from-filename.patch"
+    epatch "${FILESDIR}/${P}-0004-bookmarks-only-emit-item-removed-if-actually-removed.patch"
+
+    gnome2_src_prepare
+}
+
+src_configure() {
+	# --enable-debug only changes CFLAGS, useless for us
+	# Plugins
+	# shoutcast seems to be broken
+	gnome2_src_configure \
+		--disable-static \
+		--disable-debug \
+		--disable-uninstalled \
+		--enable-bliptv \
+		--enable-apple-trailers \
+		--enable-bookmarks \
+		--enable-filesystem \
+		--enable-gravatar \
+		--enable-jamendo \
+		--enable-lastfm-albumart \
+		--enable-localmetadata \
+		--enable-magnatune \
+		--enable-metadata-store \
+		--enable-podcasts \
+		--enable-raitv \
+		--disable-shoutcast \
+		--enable-tmdb \
+		$(use_enable daap dmap) \
+		$(use_enable dvd optical-media) \
+		$(use_enable flickr) \
+		$(use_enable freebox) \
+		$(use_enable gnome-online-accounts goa) \
+		$(use_enable lua lua-factory) \
+		$(use_enable pocket) \
+		$(use_enable thetvdb) \
+		$(use_enable tracker) \
+		$(use_enable upnp-av dleyna) \
+		$(use_enable vimeo) \
+		$(use_enable youtube)
+}