- x11-terms/gnome-terminal: Bump to 3.14.2-r2.

2025-12-07 02:52:38 +01:00 · 2015-03-15 19:43:55 +01:00
parent c4ecf93945
commit cda754c221
5 changed files with 605 additions and 0 deletions
--- a/x11-terms/gnome-terminal/gnome-terminal-3.14.2-r2.ebuild
+++ b/x11-terms/gnome-terminal/gnome-terminal-3.14.2-r2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/gnome-terminal/gnome-terminal-3.14.2-r2.ebuild,v 1.3 2015/03/15 13:34:24 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 readme.gentoo
+
+DESCRIPTION="The Gnome Terminal"
+HOMEPAGE="https://wiki.gnome.org/Apps/Terminal/"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="debug +gnome-shell +nautilus"
+KEYWORDS="~alpha amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux"
+
+# FIXME: automagic dependency on gtk+[X]
+RDEPEND="
+	>=dev-libs/glib-2.40:2[dbus]
+	>=x11-libs/gtk+-3.10:3[X]
+	>=x11-libs/vte-0.38:2.91
+	>=gnome-base/dconf-0.14
+	>=gnome-base/gsettings-desktop-schemas-0.1.0
+	sys-apps/util-linux
+	x11-libs/libSM
+	x11-libs/libICE
+	gnome-shell? ( gnome-base/gnome-shell )
+	nautilus? ( >=gnome-base/nautilus-3 )
+"
+# gtk+:2 needed for gtk-builder-convert, bug 356239
+DEPEND="${RDEPEND}
+	app-text/yelp-tools
+	dev-util/appdata-tools
+	dev-util/gdbus-codegen
+	|| ( dev-util/gtk-builder-convert <=x11-libs/gtk+-2.24.10:2 )
+	>=dev-util/intltool-0.50
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+DOC_CONTENTS="To get previous working directory inherited in new opened
+	tab you will need to add the following line to your ~/.bashrc:\n
+	. /etc/profile.d/vte.sh"
+
+src_prepare() {
+	# client: Hide obsolete --title option (from '3.14')
+	epatch "${FILESDIR}/${P}-title-option.patch"
+
+	# screen: Fix crash with empty child process command line (from '3.14')
+	epatch "${FILESDIR}/${P}-fix-crash.patch"
+	epatch "${FILESDIR}/${P}-restore-transparency.patch"
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--disable-migration \
+		$(use_enable debug) \
+		$(use_enable gnome-shell search-provider) \
+		$(use_with nautilus nautilus-extension) \
+		VALAC=$(type -P true)
+		# Docs are broken in this release.
+		#ITSTOOL=$(type -P true) \
+		#XMLLINT=$(type -P true)
+}
+
+src_install() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS"
+	gnome2_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}