dev-libs/libratbag: add 0.18

dev-libs/libratbag/Manifest

@@ -0,0 +1 @@
+DIST libratbag-0.18.tar.gz 296737 BLAKE2B db691af43b3d2aeafcb31cdb4ce41504dd37a7a0a5a6d97bf2a3bee6840bbe49de25351990787436bc00a0dc80f5a20e31030069aa58ea8e38c7cad1029e39f8 SHA512 ae1796d738f7e448c6022c56cb876af5fb43e29b89fef31bbf42b9c838a07fd1d6cf94815dfde87dcd94a72bae159ca14624826b75cf83c988ba4c20340031cb

dev-libs/libratbag/files/ratbagd.init

@@ -0,0 +1,13 @@
+#!/sbin/openrc-run
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+description="system daemon to introspect and modify configurable mice"
+pidfile="/run/${SVCNAME}.pid"
+command="/usr/bin/ratbagd"
+start_stop_daemon_args="--quiet"
+command_background="true"
+
+depend() {
+	need dbus
+}

dev-libs/libratbag/libratbag-0.18.ebuild

@@ -0,0 +1,108 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson python-single-r1 systemd udev
+
+DESCRIPTION="Library to configure gaming mice"
+HOMEPAGE="https://github.com/libratbag/libratbag"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/libratbag/libratbag.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc elogind systemd test"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	^^ ( elogind systemd )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-lang/swig
+	virtual/pkgconfig
+	doc? (
+		$(python_gen_cond_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		')
+	)
+	test? (
+		dev-libs/check
+		dev-libs/gobject-introspection
+		dev-debug/valgrind
+		$(python_gen_cond_dep '
+			dev-python/evdev[${PYTHON_USEDEP}]
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	acct-group/plugdev
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libevdev
+	dev-libs/libunistring:=
+	virtual/libudev:=
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/evdev[${PYTHON_USEDEP}]
+	')
+	elogind? ( sys-auth/elogind )
+	systemd? ( sys-apps/systemd )
+"
+DEPEND="
+	${RDEPEND}
+	dev-libs/gobject-introspection
+"
+
+src_prepare() {
+	default
+
+	if use elogind ; then
+		# Fix systemd includes for elogind
+		sed -i -e 's@include <systemd@include <elogind@' \
+			ratbagd/ratbag*.c || die
+	fi
+}
+
+src_configure() {
+	python_setup
+
+	local emesonargs=(
+		$(meson_use doc documentation)
+		$(meson_use systemd)
+		$(meson_use test tests)
+		-Ddbus-group="plugdev"
+		-Dlogind-provider=$(usex elogind elogind systemd)
+		-Dsystemd-unit-dir="$(systemd_get_systemunitdir)"
+		-Dudev-dir="${EPREFIX}$(get_udevdir)"
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}"/usr/bin/
+	newinitd "${FILESDIR}"/ratbagd.init ratbagd
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]] ; then
+		elog 'You need to be in "plugdev" group in order to access the'
+		elog 'ratbagd dbus interface'
+	fi
+	elog 'You may be required to create and/or be part of the "games" group if you intend on using piper'
+}

dev-libs/libratbag/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>david.guglielmi@gmail.com</email>
+    <name>David GUGLIELMI</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">libratbag/libratbag</remote-id>
+  </upstream>
+</pkgmetadata>