-media-sound/mixxx: bump to 2.0.0-rc2

2025-12-06 13:52:40 +01:00 · 2015-12-19 17:32:07 +01:00
parent 88433aaa0f
commit a1e9f69867
3 changed files with 188 additions and 0 deletions
--- a/media-sound/mixxx/mixxx-2.0.0_rc2.ebuild
+++ b/media-sound/mixxx/mixxx-2.0.0_rc2.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit eutils multilib scons-utils toolchain-funcs
+
+DESCRIPTION="A Qt based Digital DJ tool"
+HOMEPAGE="http://www.mixxx.org/"
+SRC_URI="https://github.com/mixxxdj/${PN}/archive/release-${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="aac debug doc ffmpeg hid mp3 mp4 pulseaudio +qt4 qt5 shout wavpack"
+REQUIRED_USE="^^ ( qt4 qt5 )"
+
+RDEPEND="dev-libs/protobuf
+	media-libs/chromaprint
+	media-libs/flac
+	media-libs/libid3tag
+	media-libs/libogg
+	media-libs/libsndfile
+	>=media-libs/libsoundtouch-1.5
+	media-libs/libvorbis
+	>=media-libs/portaudio-19_pre
+	media-libs/portmidi
+	media-libs/rubberband
+	media-libs/taglib
+	media-libs/vamp-plugin-sdk
+	sci-libs/fftw:3.0
+	virtual/glu
+	virtual/opengl
+	qt4? (
+		dev-qt/qtgui:4
+		dev-qt/qtopengl:4
+		dev-qt/qtsql:4
+		dev-qt/qtsvg:4
+		dev-qt/qttest:4
+		dev-qt/qtwebkit:4
+		dev-qt/qtxmlpatterns:4
+	)
+	qt5? (
+		>=dev-qt/qtscript-5.4.2:5[scripttools]
+		>=dev-qt/qtsvg-5.4.2:5
+		>=dev-qt/qtsql-5.4.2:5
+		>=dev-qt/qtxml-5.4.2:5
+		>=dev-qt/qtopengl-5.4.2:5
+		>=dev-qt/qtgui-5.4.2:5
+		>=dev-qt/qtnetwork-5.4.2:5
+		>=dev-qt/qtcore-5.4.2:5
+		>=dev-qt/qtwidgets-5.4.2:5
+		>=dev-qt/qttest-5.4.2:5
+		>=dev-qt/qtxmlpatterns-5.4.2:5
+		>=dev-qt/qtconcurrent-5.4.2:5
+	)
+	aac? (
+		media-libs/faad2
+		media-libs/libmp4v2:0
+	)
+	hid? ( dev-libs/hidapi )
+	mp3? ( media-libs/libmad )
+	mp4? ( media-libs/libmp4v2:= )
+	ffmpeg? ( virtual/ffmpeg )
+	pulseaudio? ( media-sound/pulseaudio )
+	shout? ( media-libs/libshout )
+	wavpack? ( media-sound/wavpack )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${PN}-release-${PV/_/-}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.0.0_rc1-system-libs.patch
+	epatch "${FILESDIR}"/${PN}-2.0.0_rc1-docs.patch
+	epatch "${FILESDIR}"/${P}-fix-qtgl-build.patch
+
+	# use multilib compatible directory for plugins
+	sed -i -e "/unix_lib_path =/s/'lib'/'$(get_libdir)'/" src/SConscript || die
+}
+
+src_configure() {
+	if use qt5 ; then
+		QTDIR=${EPREFIX}/usr/$(get_libdir)/qt5
+	else
+		QTDIR=${EPREFIX}/usr/$(get_libdir)/qt4
+	fi
+
+	myesconsargs=(
+		prefix="${EPREFIX}/usr"
+		qtdir="${QTDIR}"
+		hifieq=1
+		vinylcontrol=1
+		optimize=0
+		$(use_scons qt5)
+		$(use_scons aac faad)
+		$(use_scons debug qdebug)
+		$(use_scons hid hid)
+		$(use_scons mp3 mad)
+		$(use_scons mp4 m4a)
+		$(use_scons ffmpeg)
+		$(use_scons shout shoutcast)
+		$(use_scons wavpack wv)
+	)
+}
+
+src_compile() {
+	CC="$(tc-getCC)" CXX="$(tc-getCXX)" LINKFLAGS="${LDFLAGS}" \
+	LIBPATH="${EPREFIX}/usr/$(get_libdir)" escons
+}
+
+src_install() {
+	CC="$(tc-getCC)" CXX="$(tc-getCXX)" LINKFLAGS="${LDFLAGS}" \
+	LIBPATH="${EPREFIX}/usr/$(get_libdir)" escons install \
+		install_root="${ED}"/usr
+
+	dodoc README Mixxx-Manual.pdf
+}