media-video/clapper: add 0.10.0

media-video/clapper/Manifest

@@ -1 +1,2 @@
+DIST clapper-0.10.0.tar.gz 444586 BLAKE2B 22252f7470b70b41451023039b27e5bed6265d6782912dcad22af7532670f59d4463cc86c2fbeb168c9dda7016a4b175479a4bd93883f34eee07535af767d847 SHA512 b9f36ffecaedceb8779c6328896226a02fa730123d05c7d6f4738e647d0513cabc5ef52dd299a832405ab7e787cd14cc1b7edac3883375b47577017ba3f75e76
 DIST clapper-0.8.0.tar.gz 370473 BLAKE2B e54f5f590dff25ebaad523bf6236099ce2249463ac556c1e5fe27437a5ebd658a5296315daa60530b53e45cc15caf41b464f58a277ffa604f32eaa3ea6ca3c15 SHA512 2690eb37918a84af0258813e3005ff3b6050e1d9da38ac42036e3e03b5f4807f53fcf9353938aebcc9859dbb00aca12792ad166fdf774787b5d1cc27c6b2ef1e

media-video/clapper/clapper-0.10.0.ebuild

@@ -0,0 +1,86 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VALA_MIN_API_VERSION="0.56"
+VALA_USE_DEPEND="vapigen"
+
+inherit meson vala gnome2-utils
+
+DESCRIPTION="Modern media player designed for simplicity"
+HOMEPAGE="https://github.com/Rafostar/clapper"
+SRC_URI="
+	https://github.com/Rafostar/clapper/archive/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="GPL-3 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="doc gstreamer introspection plugins +server vala"
+
+REQUIRED_USE="doc? ( introspection )"
+
+DEPEND="
+	>=dev-libs/glib-2.76.0
+	>=media-libs/gstreamer-1.24.0:=
+	>=gui-libs/gtk-4.10.0
+	>=gui-libs/libadwaita-1.5.0
+	>=media-libs/gst-plugins-base-1.24.0
+	introspection? ( dev-libs/gobject-introspection )
+	plugins? ( dev-libs/libpeas:2 )
+	server? (
+		net-libs/libsoup:3.0
+		net-libs/libmicrodns
+	)
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	vala? ( $(vala_depend) )
+	doc? (
+		dev-util/gi-docgen
+		media-gfx/graphviz
+	)
+"
+
+src_prepare() {
+	use vala && vala_setup
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dclapper=enabled
+		-Dclapper-gtk=enabled
+		-Dclapper-app=enabled
+		$(meson_feature gstreamer gst-plugin)
+		$(meson_feature introspection)
+		$(meson_feature vala vapi)
+		$(meson_use doc)
+		$(meson_feature plugins enhancers-loader)
+		-Ddiscoverer=enabled
+		-Dmpris=enabled
+		$(meson_feature server)
+		$(meson_feature gstreamer glimporter)
+		$(meson_feature gstreamer gluploader)
+		$(meson_feature gstreamer rawimporter)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}