media-libs/libcamera: add 0.5.2

media-libs/libcamera/Manifest

@@ -1,2 +1,3 @@
 DIST libcamera-v0.4.0.tar.bz2 1315742 BLAKE2B 284bffbaf9f5e7235c9835717c601d346fbb67c326e4a4f42281a4da2d75cc915166f7fd3267f0dc87eda883ecff684c51338ed5212427a7f24b27ba9c8056f0 SHA512 dd097461cc5bc834cdd6c43e872a32aee55ee7276b850600d705461aa9279144163b6d0374a63b27bec3f866973d4a44a9f89eacf1d40468a33faec1ffbc75b4
 DIST libcamera-v0.5.0.tar.bz2 1451501 BLAKE2B f1086a84eb0d6a3c99a86eb233d5b524c7c9b3889588e2c099fe8924ff256b90b91251cf470fd3dacd71005ba3f9e27829d0d70f2d0cb269735aa321880995f4 SHA512 a1520929cf77ba88a101e64e37c5400572e47422c5bf5a57a5b17915ba87ab4a62f3e4f8119bc3ddde91aaaf8425fe5406b24e6c72fb7e0bea47f168b8d7e1c8
+DIST libcamera-v0.5.2.tar.bz2 1495582 BLAKE2B 84bf2236d4b124047abcd3893622d1656ac57a1b1f3d88e67cefb346541b75f0b34e7d9780349cee761af98f02b4988e6d5c8e4f2a446e17028ef150b7512669 SHA512 c10bd6921cd5307dc88b7f710fd2e69c69b8c90dab2ca29c8e45e3dc5703335a6b5e7482e9de950bf56d25f2482f4640a35f29715f7e30bc02ad1a9167dd98fd

media-libs/libcamera/libcamera-0.5.2.ebuild

@@ -0,0 +1,105 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..13} )
+
+inherit meson python-single-r1
+
+DESCRIPTION="An open source camera stack and framework for Linux, Android, and ChromeOS"
+HOMEPAGE="https://libcamera.org/"
+SRC_URI="https://gitlab.freedesktop.org/camera/libcamera/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+S="${WORKDIR}/${PN}-v${PV}"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="+app debug gstreamer python qt6 trace udev unwind v4l"
+#IUSE=+" doc test"
+
+DEPEND="
+	dev-libs/libyaml:=
+	|| (
+		dev-libs/openssl
+		net-libs/gnutls
+	)
+	app? (
+		dev-libs/libevent:=
+		x11-libs/libdrm:=
+		media-libs/libjpeg-turbo:=
+		media-libs/libsdl2
+	)
+	debug? ( dev-libs/elfutils:= )
+	gstreamer? (
+		media-libs/gstreamer:=
+		media-libs/gst-plugins-base )
+	qt6? (
+		dev-qt/qtbase[gui,opengl,widgets]
+		media-libs/tiff
+	)
+	python? (
+		$(python_gen_cond_dep '
+				dev-python/jinja2[${PYTHON_USEDEP}]
+				dev-python/ply[${PYTHON_USEDEP}]
+				dev-python/pyyaml[${PYTHON_USEDEP}]
+				dev-python/pybind11[${PYTHON_USEDEP}]
+			')
+	)
+	trace? ( dev-util/lttng-ust:= )
+	udev? ( virtual/libudev )
+	unwind? ( sys-libs/libunwind:= )
+"
+#BDPEND="
+#	doc? (
+#		app-text/doxygen[dot]
+#		dev-python/sphinx
+#		dev-texlive/texlive-latexextra
+#	)
+#"
+RDEPEND="
+	${DEPEND}
+	python? ( ${PYTHON_DEPS} )
+	trace? ( dev-util/lttng-tools )
+"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+src_prepare() {
+	if use python; then
+		sed -i -e \
+			"/^destdir =/s#=.*#= '$(python_get_sitedir)/libcamera'#g" \
+			src/py/libcamera/meson.build || die
+	fi
+
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dandroid=disabled
+		$(meson_feature app cam)
+		# Building documentation is broken
+		# $(meson_feature doc documentation)
+		-Ddocumentation=disabled
+		$(meson_feature gstreamer)
+		$(meson_feature python pycamera)
+		$(meson_feature qt6 qcam)
+		$(meson_feature udev)
+		# Depend on libyuv
+		# $(meson_use test)
+		-Dtest=false
+		-Dpipelines=imx8-isi,ipu3,mali-c55,rkisp1,rpi/vc4,simple,uvcvideo,vimc
+		-Dbuildtype=$(usex debug debug plain)
+		$(meson_feature v4l v4l2)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use python; then
+		python_optimize "${D}/$(python_get_sitedir)/libcamera"
+	fi
+}