- Now available in gx86.

dev-libs/gom/Manifest

@@ -1,2 +0,0 @@
-DIST gom-0.3.1.tar.xz 385836 SHA256 7951eb46ee784cbdbee6e3f2da084ffbf776c11ca1c904404b05feafe37e38f5 SHA512 7596b7be0de6f10ef1fbe8a278d917c07ecc714e9af24f2b61a7d871c6a1b1cf19ea92d5b4fbf7802c9c097dc2ae7a65ac47b8ca8f6689b49a3e4930cff6d54c WHIRLPOOL 9fa3a42411e3892a3648f31614462d43b5a4f52a166e5edd80e97741427a9444c39d2200a4ce1ac3e1e87d3b3e974b9dad6f11ee252ba3d10fa1d63b00a09bde
-EBUILD gom-0.3.1.ebuild 841 SHA256 f14218aa2f7e67346e7985a538dd7b772f8dc400e9ca7b83fb9d134e43915811 SHA512 1e66ffcb733ebfd4ee39c8bfe522c7de6e62a3f9ca8378d4487158ab7c838a8b8743d1a7fa0adc8039e3ae061e93ffa17423498476a91b3d6a80e897441bc7f8 WHIRLPOOL e4e941b1f8f8ce3bbe6160251023374899b5d0b82dc506af38cb7b4610f8a88fea8764c500f578deebcd15bf68e7876687259b86b3d8925da99ed34ff5804b93

dev-libs/gom/gom-0.3.1.ebuild

@@ -1,37 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/gom/gom-0.3.0.ebuild,v 1.5 2015/04/11 10:15:38 pacho Exp $
-
-EAPI="5"
-GCONF_DEBUG="yes"
-
-inherit gnome2
-
-DESCRIPTION="GObject to SQLite object mapper library"
-HOMEPAGE="https://wiki.gnome.org/Projects/Gom"
-
-LICENSE="LGPL-2+"
-SLOT="0"
-
-IUSE="+introspection test"
-KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
-
-RDEPEND="
-	>=dev-db/sqlite-3.7:3
-	>=dev-libs/glib-2.36:2
-	introspection? ( >=dev-libs/gobject-introspection-1.30.0 )
-"
-DEPEND="${RDEPEND}
-	>=dev-util/gtk-doc-am-1.14
-	>=dev-util/intltool-0.40.0
-	sys-devel/gettext
-	virtual/pkgconfig
-	test? ( x11-libs/gdk-pixbuf )
-"
-
-src_configure() {
-	gnome2_src_configure \
-		--disable-static \
-		$(use_enable introspection) \
-		$(use_enable test glibtest)
-}

media-libs/grilo/Manifest

@@ -1,2 +0,0 @@
-DIST grilo-0.2.12.tar.xz 617284 SHA256 55b4663550bc8185f8db232e96b9ba99fbfa9175e31e7321fa5ccaacf3617b85 SHA512 a8102dc66e30676a3fcf2be1c96b4c461b78095c03d7566216bb6c04f875b3be6a305d81464058a11f92dee00e68b2abdcb8d5c5f2a0d95732ac7dbb473820f4 WHIRLPOOL fece087c8003138e9b6a977cb3c9d60dd41364dd6b7cb2efe98efab863e38ea360daf44b90ec7a970810a8b4a980221ef73e8a4606dca8e26e52f36980ba9ffc
-EBUILD grilo-0.2.12.ebuild 2279 SHA256 7bf4a867401260f327c6937f93ca12c7c6f57405e9f0989791c5a97675948992 SHA512 eb962a610155bbed3c4559384932f48054fd98b4d0ff22bd79659b8559f421c8dc27200da59bbddf177badab2e30c913b48fafe8e61548fe5949e43dcfa41fb4 WHIRLPOOL 0c491473c37653f70dcfef2cf30a6a73a416422ad92494b517d3b5d7e57c20995def19c2547dec59eca35ac856b32e8cb1a8b02cdac5c4d8e5f9b9573f9a973d

media-libs/grilo/grilo-0.2.12.ebuild

@@ -1,87 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/grilo/grilo-0.2.11.ebuild,v 1.4 2015/04/08 17:59:35 mgorny Exp $
-
-EAPI="5"
-GCONF_DEBUG="no" # --enable-debug only changes CFLAGS
-GNOME2_LA_PUNT="yes"
-PYTHON_COMPAT=( python2_7 )
-VALA_MIN_API_VERSION="0.12"
-VALA_USE_DEPEND="vapigen"
-
-inherit gnome2 python-any-r1 vala
-
-DESCRIPTION="A framework for easy media discovery and browsing"
-HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
-
-LICENSE="LGPL-2.1+"
-SLOT="0.2/1" # subslot is libgrilo-0.2 soname suffix
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
-
-IUSE="gtk examples +introspection +network playlist test vala"
-REQUIRED_USE="test? ( introspection )"
-
-RDEPEND="
-	>=dev-libs/glib-2.34:2
-	dev-libs/libxml2:2
-	net-libs/liboauth
-	gtk? ( >=x11-libs/gtk+-3:3 )
-	introspection? ( >=dev-libs/gobject-introspection-0.9 )
-	network? ( >=net-libs/libsoup-2.41.3:2.4 )
-	playlist? ( >=dev-libs/totem-pl-parser-3.4.1 )
-"
-DEPEND="${RDEPEND}
-	>=dev-util/gtk-doc-am-1.10
-	>=dev-util/intltool-0.40
-	virtual/pkgconfig
-	vala? ( $(vala_depend) )
-	test? (
-		$(python_gen_any_dep '
-			dev-python/pygobject:2[${PYTHON_USEDEP}]
-			dev-python/pygobject:3[${PYTHON_USEDEP}]')
-		media-plugins/grilo-plugins:0.2 )
-"
-# eautoreconf requires gnome-common
-
-python_check_deps() {
-	has_version "dev-python/pygobject:2[${PYTHON_USEDEP}]" && \
-		has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	use test && python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	# Don't build examples
-	sed -e '/SUBDIRS/s/examples//' \
-		-i Makefile.am -i Makefile.in || die
-
-	use vala && vala_src_prepare
-	gnome2_src_prepare
-}
-
-src_configure() {
-	# --enable-debug only changes CFLAGS, useless for us
-	gnome2_src_configure \
-		--disable-static \
-		--disable-debug \
-		$(use_enable gtk test-ui) \
-		$(use_enable introspection) \
-		$(use_enable network grl-net) \
-		$(use_enable playlist grl-pls) \
-		$(use_enable test tests) \
-		$(use_enable vala)
-}
-
-src_install() {
-	gnome2_src_install
-	# Upstream made this conditional on gtk-doc build...
-	emake -C doc install DESTDIR="${ED}"
-
-	if use examples; then
-		# Install example code
-		insinto /usr/share/doc/${PF}/examples
-		doins "${S}"/examples/*.c
-	fi
-}

media-libs/libmediaart/Manifest

@@ -1,3 +0,0 @@
-AUX libmediaart-qt-version-automagic-fix.patch 1776 SHA256 97f5b5e052e41689147406e6a22de122b1003f90baec7db78ddf204c0a6d6dd9 SHA512 6c9b0b34ad7ac640e8c43657c45793a4fadb1bac0b0a67d2ad01c3cf5db3ef0d07707ae71b57489b83879295f8c15e03a2ff4b5e1dc559b7d5b8882fef28b784 WHIRLPOOL 63257ae08744e9501a8ed00dc7bde86a4d628b1877272142542a394726b121bf422b438c63fb41381b4c0ec21cb0c504d08729a1a45b748e7636c97bd1f11d8a
-DIST libmediaart-1.9.0.tar.xz 5814844 SHA256 94668adb29d4dc3115b0fd105942ebd5ca6f5f9dbb2afa8a191a73a747dd506f SHA512 fcfdad1d62710a39ea21daf23b13eb0b6d64a521f359153bb79247bae8e91fde3d879f807ed2528f3476425f5214cae755b117b4d06d78ee3af41bcc9a3b3ab4 WHIRLPOOL a78cf905853873d5f778b7ae157b2b260a55e3b07ff59d93fa7f95efb53f2b2adb918bb1a5eecc8a66e6d59ee172e9dea04bbadca4bdc20766d710127b1fef79
-EBUILD libmediaart-1.9.0.ebuild 1614 SHA256 af03e9a9063f1f069ef027543d2304809f386865e2e6abd1bbeff98fc70e0cbf SHA512 d96127603712d3b501c33a93c28b61825d655b8db707aa9eceecdd290372011e10615401cf9e231690693b20ee0b4e2e3b0f0471cff247411bba57f5ea9c6479 WHIRLPOOL 547b592557caa327d495c31daf2a3338126e1b138027da34b76a2ac2cd7a0cc6f6cf0a587ece6833204925d2acd365dbd835f07f6d03571a5bd5bf1ae76375f5

media-libs/libmediaart/files/libmediaart-qt-version-automagic-fix.patch

@@ -1,47 +0,0 @@
-Solves automagic selection of Qt version.
-
-https://bugs.gentoo.org/show_bug.cgi?id=523122
-https://bugzilla.gnome.org/show_bug.cgi?id=737174
-
-diff --git a/configure.ac b/configure.ac
-index e9ead09..3ee710a 100644
---- a/configure.ac
-+++ b/configure.ac
-@@ -206,6 +206,10 @@ AC_ARG_ENABLE(qt,
-               AS_HELP_STRING([--enable-qt],
-                              [enable Qt support, (MP3 album art) [[default=auto]]]),,
-               [enable_qt=auto])
-+AC_ARG_WITH(qt-version,
-+            AS_HELP_STRING([--with-qt-version=major],
-+                           [Force specific Qt version [[default=auto]]]),,
-+            [with_qt_version=auto])
- 
- selected_for_media_art="no  (disabled)"
- 
-@@ -218,14 +222,18 @@ if test "x$enable_qt" == "xyes" && test "x$enable_gdkpixbuf" == "xyes"; then
- fi
- 
- if test "x$enable_qt" != "xno" && test "x$enable_gdkpixbuf" != "xyes"; then
--   PKG_CHECK_MODULES(QT5,
--                     [Qt5Gui >= $QT5_REQUIRED],
--                     [have_qt5=yes],
--                     [have_qt5=no])
--   PKG_CHECK_MODULES(QT4,
--                     [QtGui >= $QT4_REQUIRED],
--                     [have_qt4=yes],
--                     [have_qt4=no])
-+   if test "x$with_qt_version" == "xauto" || test "x$with_qt_version" == "x5"; then
-+       PKG_CHECK_MODULES(QT5,
-+                         [Qt5Gui >= $QT5_REQUIRED],
-+                         [have_qt5=yes],
-+                         [have_qt5=no])
-+   fi
-+   if test "x$with_qt_version" == "xauto" || test "x$with_qt_version" == "x4"; then
-+       PKG_CHECK_MODULES(QT4,
-+                         [QtGui >= $QT4_REQUIRED],
-+                         [have_qt4=yes],
-+                         [have_qt4=no])
-+   fi
- 
-    if test "x$have_qt5" = "xyes"; then
-       BACKEND_CFLAGS="$QT5_CFLAGS -fPIC"

media-libs/libmediaart/libmediaart-1.9.0.ebuild

@@ -1,67 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediaart/libmediaart-0.7.0.ebuild,v 1.7 2015/03/15 13:28:53 pacho Exp $
-
-EAPI="5"
-GCONF_DEBUG="no"
-VALA_USE_DEPEND="vapigen"
-VALA_MIN_API_VERSION="0.16"
-
-inherit autotools gnome2 vala virtualx
-
-DESCRIPTION="Manages, extracts and handles media art caches"
-HOMEPAGE="https://github.com/GNOME/libmediaart"
-
-LICENSE="LGPL-2.1+"
-SLOT="2.0"
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ppc ppc64 ~sparc ~x86"
-IUSE="gtk +introspection qt4 qt5 vala"
-REQUIRED_USE="
-	?? ( gtk qt4 qt5 )
-	vala? ( introspection )
-"
-
-RDEPEND="
-	>=dev-libs/glib-2.38.0:2
-	gtk? ( >=x11-libs/gdk-pixbuf-2.12:2 )
-	introspection? ( >=dev-libs/gobject-introspection-1.30 )
-	qt4? ( dev-qt/qtgui:4 )
-	qt5? ( dev-qt/qtgui:5 )
-"
-DEPEND="${RDEPEND}
-	>=dev-util/gtk-doc-am-1.8
-	virtual/pkgconfig
-	vala? ( $(vala_depend) )
-"
-
-src_prepare() {
-
-    sed -i 's#DOC_MODULE=libmediaart#DOC_MODULE=libmediaart2#1' ${S}/docs/reference/libmediaart/Makefile.am
-
-	use vala && vala_src_prepare
-	epatch "${FILESDIR}/${PN}-qt-version-automagic-fix.patch" #523122
-	eautoreconf
-	gnome2_src_prepare
-}
-
-src_configure() {
-	local myconf=""
-	if use qt4 ; then
-		myconf="${myconf} --enable-qt --with-qt-version=4"
-	elif use qt5 ; then
-		myconf="${myconf} --enable-qt --with-qt-version=5"
-	else
-		myconf="${myconf} --disable-qt"
-	fi
-
-	gnome2_src_configure \
-		--enable-unit-tests \
-		$(use_enable gtk gdkpixbuf) \
-		$(use_enable introspection) \
-		$(use_enable vala) \
-		${myconf}
-}
-
-src_test() {
-	dbus-launch Xemake check #513502
-}

media-plugins/grilo-plugins/Manifest

@@ -1,2 +0,0 @@
-DIST grilo-plugins-0.2.14.tar.xz 1036824 SHA256 d0f18116675058c7e8c178b1fe26d6d73998a0452f85a73b1696df740c83d3ab SHA512 d4caddb5a710f19365d1d9e890b1d525b96e78cf2228a886f1b2c66e60601c2bef61791007d0d9cc8d3b306aac3065c0ff618ef522c7971885c95ca2e365c69b WHIRLPOOL 40899069c626a4183a9cf2afe94f8290dd39bd0bed8475b5d0732d3aa2521eb6fb6f275fba38d47b0614a9e16501f63ee0c5180dd88082ceb14bff0867f7cfe5
-EBUILD grilo-plugins-0.2.14.ebuild 2478 SHA256 5eb207cef45897c326cd092c4ed905d64ca904e1d38a187a3245173d89947c25 SHA512 405aa06eeda582ad497fcbcdc570368ccb724e727760a02271243d406910c6658610e7a61a0dbbd79f12738500b723e21c8306e9b3d7e5e738c2a2f8c99e7f4f WHIRLPOOL 94dc5084a913e6ac2242fa95697a81c62a1d4602b87775598aa423f045342fea590ebb864fa2ee7990b678111ba8679a941c7a58a117ab8e798ce049d2c539ee

media-plugins/grilo-plugins/grilo-plugins-0.2.14.ebuild

@@ -1,94 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/grilo-plugins/grilo-plugins-0.2.13.ebuild,v 1.6 2015/02/23 11:59:50 pacho Exp $
-
-EAPI="5"
-GCONF_DEBUG="no" # --enable-debug only changes CFLAGS
-GNOME2_LA_PUNT="yes"
-
-inherit gnome2
-
-DESCRIPTION="A framework for easy media discovery and browsing"
-HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
-
-LICENSE="LGPL-2.1+"
-SLOT="0.2"
-KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
-IUSE="daap +dvd flickr freebox gnome-online-accounts lua pocket thetvdb tracker upnp-av +vimeo +youtube"
-
-RDEPEND="
-	>=dev-libs/glib-2.36:2
-	>=media-libs/grilo-0.2.11:${SLOT}[network,playlist]
-	>=media-libs/libmediaart-1.9:2.0
-	>=dev-libs/gom-0.2.1
-
-	dev-libs/gmime:2.6
-	dev-libs/json-glib
-	dev-libs/libxml2:2
-	dev-db/sqlite:3
-
-	daap? ( >=net-libs/libdmapsharing-2.9.12:3.0 )
-	dvd? ( >=dev-libs/totem-pl-parser-3.4.1 )
-	flickr? ( net-libs/liboauth )
-	freebox? ( net-dns/avahi )
-	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.7.1 )
-	lua? (
-		>=dev-lang/lua-5.2
-		app-arch/libarchive )
-	pocket? (
-		>=net-libs/gnome-online-accounts-3.11.4
-		>=net-libs/rest-0.7.90
-		>=dev-libs/totem-pl-parser-3.4.1 )
-	thetvdb? (
-		app-arch/libarchive
-		dev-libs/libxml2 )
-	tracker? ( >=app-misc/tracker-0.10.5:= )
-	youtube? (
-		>=dev-libs/libgdata-0.9.1:=
-		dev-libs/totem-pl-parser )
-	upnp-av? ( net-libs/libsoup )
-	vimeo? (
-		dev-libs/totem-pl-parser )
-"
-DEPEND="${RDEPEND}
-	app-text/docbook-xml-dtd:4.5
-	app-text/yelp-tools
-	>=dev-util/intltool-0.40.0
-	virtual/pkgconfig
-"
-
-src_configure() {
-	# --enable-debug only changes CFLAGS, useless for us
-	# Plugins
-	# shoutcast seems to be broken
-	gnome2_src_configure \
-		--disable-static \
-		--disable-debug \
-		--disable-uninstalled \
-		--enable-bliptv \
-		--enable-apple-trailers \
-		--enable-bookmarks \
-		--enable-filesystem \
-		--enable-gravatar \
-		--enable-jamendo \
-		--enable-lastfm-albumart \
-		--enable-localmetadata \
-		--enable-magnatune \
-		--enable-metadata-store \
-		--enable-podcasts \
-		--enable-raitv \
-		--disable-shoutcast \
-		--enable-tmdb \
-		$(use_enable daap dmap) \
-		$(use_enable dvd optical-media) \
-		$(use_enable flickr) \
-		$(use_enable freebox) \
-		$(use_enable gnome-online-accounts goa) \
-		$(use_enable lua lua-factory) \
-		$(use_enable pocket) \
-		$(use_enable thetvdb) \
-		$(use_enable tracker) \
-		$(use_enable upnp-av dleyna) \
-		$(use_enable vimeo) \
-		$(use_enable youtube)
-}