x11-misc/gpaste: add 50.2

x11-misc/gpaste/Manifest

@@ -1,2 +1,3 @@
 DIST gpaste-45.3.tar.gz 404690 BLAKE2B 1cdf4adad56c1042a9ceca18ff8339c7540c8228244cec8cf83ff64727c6a7ca24c3b21f2e817f84ff437731137690d12abe3bcf8af500ec069b2e37f7675754 SHA512 4f9f17cf11fb54c8c19d36cf24a88579b98e434c280071ad9bae91e94a004699def570fb5655175e96be7c6043d3f4c5e6fbffa630e11e849fe4db04483e40da
 DIST gpaste-45.9.tar.gz 450630 BLAKE2B 3e0a43ecd0a42dafbdef32676f4b8afece95ef3706730df276a902edcbf9ba304aadbc8d624573ec287374be027a4cad99da49312a17577a9169eb13350bcabf SHA512 c4eb681056f7b6371d2a71164f74a157e1c03c8ad0febc4f94397bd12139817ec4aab75412ac2b0c7300780bb4634734d4b0bcb31c15dc7a7497e71d6382405a
+DIST gpaste-50.2.tar.gz 496474 BLAKE2B 7486b32dc2c98064f44e765dad3911cdd62e7a71189b848310feda2a7ab17f553bac436ebdd7ab5f4b66f4e47c968d2e27bae6bafd83bb6f90a8a47e18e36f05 SHA512 2fae6d327cceb962c2cf97b693cd09696b836702717fab59c0e1fc74ca4fd33fe7b6bad8e544ff3b4fec011ab76953a6a07c8d1d36023776f56fe250b50c3dd3

x11-misc/gpaste/gpaste-50.2.ebuild

@@ -0,0 +1,91 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VALA_MIN_API_VERSION="0.42"
+VALA_USE_DEPEND="vapigen"
+
+inherit meson vala gnome2-utils
+
+DESCRIPTION="Clipboard management system"
+HOMEPAGE="https://github.com/Keruspe/GPaste"
+SRC_URI="https://github.com/Keruspe/GPaste/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+S="${WORKDIR}/GPaste-${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+# Wait for GNOME 50 in ::gentoo 
+#KEYWORDS="~amd64 ~x86"
+IUSE="+gnome +introspection systemd vala"
+
+REQUIRED_USE="
+	gnome? ( introspection )
+	vala? ( introspection )
+"
+
+DEPEND="
+	>=gui-libs/libadwaita-1.9
+	>=app-crypt/gcr-3.90.0:4
+	>=x11-libs/gdk-pixbuf-2.38.0:2
+	>=dev-libs/glib-2.84.0:2
+	sys-apps/dbus
+	>=gui-libs/gtk-4.18.0:4
+	gnome? (
+		>=x11-wm/mutter-41.3
+		x11-libs/pango
+		>=dev-libs/gjs-1.78.0
+	)
+	introspection? (
+		>=dev-libs/gobject-introspection-1.48.0
+		>=x11-wm/mutter-41.3[introspection]
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+	gnome? (
+		gnome-base/gnome-control-center:2
+	)
+	systemd? (
+		sys-apps/systemd
+	)
+	vala? ( $(vala_depend) )
+"
+RDEPEND="${DEPEND}
+	gnome? (
+		gnome-base/gnome-control-center:2
+		gnome-base/gnome-shell
+	)
+	systemd? (
+		sys-apps/systemd
+	)
+"
+
+src_prepare() {
+	use vala && vala_setup
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use systemd systemd)
+		-Dbash-completion=true
+		-Dzsh-completion=true
+		-Dx-keybinder=true
+		-Dcontrol-center-keybindings-dir=$(usex gnome '' \
+		'/usr/share/gnome-control-center/keybindings')
+		$(meson_use introspection introspection)
+		$(meson_use vala vapi)
+		$(meson_use gnome gnome-shell)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}