x11-misc/gpaste: bump to 3.24.5

x11-misc/gpaste/Manifest

@@ -0,0 +1,3 @@
+DIST gpaste-3.24.5.tar.gz 163876 BLAKE2B 4542bd55c0401a8002361a0c6c740114a51bd72e0c870449bd9e42c286de437f33edb5d06a0a13c242dbca443c20ead584f7ccb2932da4071bfc2019cc2dd6c2 SHA512 6a8db589607bb4a141be2e2ef617ce2a78d56bf7ab6010214ac98e776819e1a7be48bd6b8e76e4c3bc78ab90a5ecf996724f7c4a063fdb1a5bc10f2ce134399f
+EBUILD gpaste-3.24.5.ebuild 1388 BLAKE2B 9aed48785ca6940bb5d161df5fe6ac30b74b2937aae98a5a5e27ca19e66912fe6475f75fe0811ebca6afbef7d4878ff46e9456b030f9a5d9b48df9e506ebb647 SHA512 cb12c6eb3f1bcf56f73fb260d170854574a9ac303fd13703a27493947d34000db809b097d36632ab7f34359f3220f55f1b4960c70b8cf4221e819eb68143bcbb
+MISC metadata.xml 595 BLAKE2B 7a8327f78e0e4cb106350051ff89a5677401e9ffa2d833e424da1f14a89c3147e59be124e6e0a26a3609f57c8a6078a00b6fce6a8f36889bafa5021539c0d89a SHA512 8fca7baa9d40775abe8ce7db98c5fc8e882d96e6200db5d84b6b1964369d6c499e344b30826c405368a18ca0f2caeab94d8dc44f648fe10f317075d82f60ca3d

x11-misc/gpaste/gpaste-3.24.5.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+VALA_MIN_API_VERSION="0.30"
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils autotools gnome2-utils vala vcs-snapshot
+
+DESCRIPTION="Clipboard management system"
+HOMEPAGE="https://github.com/Keruspe/GPaste"
+SRC_URI="https://github.com/Keruspe/GPaste/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+applet gnome vala"
+
+CDEPEND="
+	dev-libs/appstream-glib
+	>=dev-libs/glib-2.48:2
+	>=dev-libs/gobject-introspection-1.48.0
+	sys-apps/dbus
+	>=x11-libs/gdk-pixbuf-2.34:2
+	>=x11-libs/gtk+-3.20:3
+	x11-libs/libX11
+	x11-libs/libXi
+	gnome? (
+		gnome-base/gnome-control-center:2
+		media-libs/clutter
+		x11-libs/pango
+	)
+"
+RDEPEND="${CDEPEND}
+	gnome? (
+		gnome-base/gnome-shell
+	)
+"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	eautoreconf
+	vala_src_prepare
+
+	if ! use gnome ; then
+		echo "" > data/control-center.mk || die
+	fi
+}
+
+src_configure() {
+	econf \
+		$(use_enable vala) \
+		$(use_enable applet) \
+		--disable-unity \
+		$(use_enable gnome gnome-shell-extension) \
+		--disable-static \
+		--disable-schemas-compile
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}

x11-misc/gpaste/metadata.xml

@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>leho@kraav.com</email>
+		<name>Leho Kraav </name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<use>
+		<flag name="applet">Enable gpaste-applet</flag>
+		<flag name="gnome">Enable proper gnome support and
+			enable gnome shell extension.</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">Keruspe/GPaste</remote-id>
+	</upstream>
+</pkgmetadata>