app-misc/piper: add 0.8

app-misc/piper/Manifest

@@ -0,0 +1 @@
+DIST piper-0.8.tar.gz 318558 BLAKE2B 170426c35899841a3317d0cd37d253fab524848fbe5ebf1c2e670c56c962bf9f7a39bccd1dea43bbf0d5c6a158e795df63e84ddb0422fec4fd92142d70fccbc8 SHA512 c0a05262262a1284911c976ab934653f8a3699066ef1d791669169c1e6c5db62dba0fcccc32d6bc68b996a2c2b8e96a6567761d01417a03d7dbb41010dd95cd8

app-misc/piper/metadata.xml

@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>david.guglielmi@gmail.com</email>
+		<name>David GUGLIELMI</name>
+	</maintainer>
+	<longdescription>
+		Piper is a graphical user interface to configure gaming mice.
+		Configuration options include changing the resolution (DPI) of the
+		mouse, adding and removing profiles, setting LED colors and changing
+		button behaviors.
+
+		Piper requires <pkg>dev-libs/libratbag</pkg>’s ratbagd, the daemon to actually communicate with the
+		mice. Piper is merely a front end to ratbagd, ratbagd must be
+		installed and running when Piper is launched.
+	</longdescription>
+	<upstream>
+		<remote-id type="github">libratbag/piper</remote-id>
+		<bugs-to>https://github.com/libratbag/piper/issues</bugs-to>
+		<doc lang="en">https://github.com/libratbag/piper/wiki</doc>
+	</upstream>
+</pkgmetadata>

app-misc/piper/piper-0.8.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson python-single-r1 xdg
+
+DESCRIPTION="GTK application to configure gaming devices"
+HOMEPAGE="https://github.com/libratbag/piper"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/libratbag/piper.git"
+else
+	SRC_URI="https://github.com/libratbag/piper/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/flake8[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+	')
+	dev-libs/appstream
+	virtual/pkgconfig
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/gobject-introspection
+	>=dev-libs/libratbag-0.14
+	gnome-base/librsvg[introspection]
+	x11-libs/gdk-pixbuf[introspection]
+	x11-libs/gtk+:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/evdev[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	')
+"
+DEPEND="
+	${RDEPEND}
+	dev-libs/libevdev
+	virtual/libudev
+"
+
+src_configure() {
+	python_setup
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+	python_fix_shebang "${ED}"/usr/bin/
+}