media-tv/kodi: bump to 20.1, add somes media-plugins

media-plugins/kodi-inputstream-adaptive/Manifest

@@ -0,0 +1,3 @@
+DIST bento4-1.6.0-639-6-Nexus.tar.gz 5481704 BLAKE2B 130e5391abc3f85377a2ef2bfa992769ec188172743e6406fc96b9e561e82e0da57c77585f2cbf3e176228267d4c53920970dd1cbdc784f954130c92f77eaf61 SHA512 08c359fb75f42d095ae040fb4dff020c902ba24677a95360fb845245ba3881423961bff6c8f0d2a791d387aa58ebe50b4998bedb866e0b7b58321bf8cdd4b1c3
+DIST kodi-inputstream-adaptive-20.3.6.tar.gz 770375 BLAKE2B da8bf237f2cb9de546508dbdcc3615c9e594594c0d0467b83a4f8fb78c834a5420aa776b7ce785127833ced35e6158513ba82de850edc0133ce4fad9a6b67696 SHA512 010af7abfeeed375d4c3457f5d7a9aa848edbf247427b72f64f1f4e26870ad39ec4a9b1e6bc9479ce41dc01779f9a7d0bdbb8f005f7e8afde9ea59f9e31d879d
+EBUILD kodi-inputstream-adaptive-20.3.6.ebuild 981 BLAKE2B c586f04b82072bd8dd196dfac82ea1c6c7e8d8c68f5a7dcaf893d8fca9d7b0c5bf2183e22299df45fcf3b8bf0cffac0a56fb92fbbe63d590147feba238762e96 SHA512 b871168f7518407eb9548590b0a3f943ab4bf952cf2d7209952c27484cb9a78602a2274ba819068ed09d5ba7124f97b1230e07fc36a9469b0a7d0a22473747d7

media-plugins/kodi-inputstream-adaptive/kodi-inputstream-adaptive-20.3.6.ebuild

@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake kodi-addon
+
+DESCRIPTION="Kodi's Adaptive inputstream addon"
+HOMEPAGE="https://github.com/xbmc/inputstream.adaptive.git"
+
+CODENAME="Nexus"
+BENTO4_VERSION="1.6.0-639-6-${CODENAME}"
+
+KEYWORDS="~amd64 ~x86"
+SRC_URI="https://github.com/xbmc/inputstream.adaptive/archive/${PV}-${CODENAME}.tar.gz -> ${P}.tar.gz
+	https://github.com/xbmc/Bento4/archive/${BENTO4_VERSION}.tar.gz -> bento4-${BENTO4_VERSION}.tar.gz"
+S="${WORKDIR}/inputstream.adaptive-${PV}-${CODENAME}"
+
+LICENSE="GPL-2"
+SLOT="0"
+RESTRICT="!test? ( test )"
+IUSE="test"
+
+COMMON_DEPEND="
+	dev-libs/expat
+	=media-tv/kodi-20*
+	"
+DEPEND="
+	${COMMON_DEPEND}
+	test? ( dev-cpp/gtest )
+	"
+RDEPEND="
+	${COMMON_DEPEND}
+	"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test)
+		-DENABLE_INTERNAL_BENTO4=ON
+		-DBENTO4_URL="${DISTDIR}/bento4-${BENTO4_VERSION}.tar.gz"
+	)
+	cmake_src_configure
+}

media-plugins/kodi-inputstream-ffmpegdirect/Manifest

@@ -0,0 +1,2 @@
+DIST kodi-inputstream-ffmpegdirect-20.5.0.tar.gz 289362 BLAKE2B 2e8c63bd47d54f84cade2acb092a8e3ef11c31170071f66b5f22d4aa6fd27992a22b19ecb8070ce7d952f80882fe617e5eaed70dcf325b9bdb579220ddd59688 SHA512 9db8e25f04400635e13cf7c79f7079be9c7ffbf427423abcfc449dcd06f6259dcf9ed1ad1eae1563db239978c8399e054e7c6adcbebb5cc70c4de1c01643d074
+EBUILD kodi-inputstream-ffmpegdirect-20.5.0.ebuild 805 BLAKE2B d52c444fd39a4c0a14db34bf625e8fe5bb0bb23d23435705a2bb9c543b02f5bd89609f95e1c87ecb29b5a9a9fbea755b91a37b428ffb2ec33909eeed4613efcb SHA512 46fe414104a4e0a2b63f50fd5f114065bf2cd7cf961ddd2d69eea36d6472b5de19003832b64564fe34d3238743c44921de038ac03148d339d1523f43bc5685f6

media-plugins/kodi-inputstream-ffmpegdirect/kodi-inputstream-ffmpegdirect-20.5.0.ebuild

@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake kodi-addon
+
+DESCRIPTION="Kodi's FFMpeg Direct Inputstream addon"
+HOMEPAGE="https://github.com/xbmc/inputstream.ffmpegdirect"
+SRC_URI=""
+
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+CODENAME="Nexus"
+SRC_URI="https://github.com/xbmc/inputstream.ffmpegdirect/archive/${PV}-${CODENAME}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/inputstream.ffmpegdirect-${PV}-${CODENAME}"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+BDEPEND="
+	virtual/pkgconfig
+	"
+
+COMMON_DEPEND="
+	media-video/ffmpeg[encode,libxml2,zlib]
+	virtual/libiconv
+	app-arch/bzip2
+	=media-tv/kodi-20*
+	"
+
+DEPEND="
+	${COMMON_DEPEND}
+	"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	"
+
+src_prepare() {
+	[ -d depends ] && rm -rf depends || die
+	cmake_src_prepare
+}

media-plugins/kodi-inputstream-rtmp/Manifest

@@ -0,0 +1,2 @@
+DIST kodi-inputstream-rtmp-20.3.0.tar.gz 88703 BLAKE2B 226ffca80634a05bfd7be268f7a024c5f9d54e9c561da213fe53a3369e7657fa92549e3a5107899d9304d382997bf502092fe21f09e6e013858b0de2828caaef SHA512 4c70d3df184eae19e359460560257012fece6cbd571d9a27c01f0dbdff84f1ce12b88527a1797cdc3c2a12e39edb92a7a82dd1cfd5721b553290a295733df9f6
+EBUILD kodi-inputstream-rtmp-20.3.0.ebuild 707 BLAKE2B edafe77a036dbaaf21eccb094922667c76b5b09d3cc72d9c66349d4ac578a1b8af43d843088619cc4cf90a57834d00a9b81ac2c8e808d854a8dd054d618bc6a8 SHA512 292d331ee6d35e12bbf60859e1746150d6e8a7d4c1f3127d15209d0342754a31a12ea8c3d5b45fe27ed90365214ea8df963b1eb0c2bde2f506096618d911ad05

media-plugins/kodi-inputstream-rtmp/kodi-inputstream-rtmp-20.3.0.ebuild

@@ -0,0 +1,34 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kodi-addon
+
+DESCRIPTION="Kodi's RTMP inputstream addon"
+HOMEPAGE="https://github.com/xbmc/inputstream.rtmp"
+KODI_PLUGIN_NAME="inputstream.rtmp"
+
+CODENAME="Nexus"
+KEYWORDS="~amd64 ~x86"
+SRC_URI="https://github.com/xbmc/${KODI_PLUGIN_NAME}/archive/${PV}-${CODENAME}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${KODI_PLUGIN_NAME}-${PV}-${CODENAME}"
+DEPEND="=media-tv/kodi-20*:="
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+
+DEPEND+="
+	media-video/rtmpdump[ssl]
+	"
+
+RDEPEND="${DEPEND}"
+
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	if [ -d depends ]; then rm -rf depends || die; fi
+
+	cmake_src_prepare
+}

media-plugins/kodi-pvr-hts/Manifest

@@ -0,0 +1,2 @@
+DIST kodi-pvr-hts-20.6.2.tar.gz 218204 BLAKE2B 6e2fee04bf5b2efd85f3a02ef2edf91637a20c06e364895c6f56b47e973b9c951ecf6035147383ec09d09c532a72e21e3becdf51c1ba1af8be259a201355da6d SHA512 8213b2d061abc3eeb8253426c37425826ed00450e43cc1561d154311b19d5280190e3ad09666cb01134a72ac02956395a56a36e78eb97c88f88cb8ded7eaad2f
+EBUILD kodi-pvr-hts-20.6.2.ebuild 533 BLAKE2B 07c143a1238780c37408bf45965d13126d554f4bb5cb0e10f1b319ee51f283265b189a949dedf60a4d6a7adfd43bb156524d187523247ecff70af7dcb95ae36c SHA512 aa3072bb411bc3c393f80767d68a217ac56873997eddb38c721a2a668c770b69d85781cfd90538751f32cc518554776a8e9f4b16d98ad94359fbceade63f423f

media-plugins/kodi-pvr-hts/kodi-pvr-hts-20.6.2.ebuild

@@ -0,0 +1,27 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake kodi-addon
+
+DESCRIPTION="Tvheadend Live TV and Radio PVR client addon for Kodi"
+HOMEPAGE="https://github.com/kodi-pvr/pvr.hts"
+SRC_URI=""
+
+CODENAME="Nexus"
+KEYWORDS="~amd64 ~x86"
+SRC_URI="https://github.com/kodi-pvr/pvr.hts/archive/${PV}-${CODENAME}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/pvr.hts-${PV}-${CODENAME}"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+DEPEND="
+	=media-tv/kodi-20*
+	"
+
+RDEPEND="
+	${DEPEND}
+	"

media-plugins/kodi-pvr-iptvsimple/Manifest

@@ -0,0 +1,2 @@
+DIST kodi-pvr-iptvsimple-20.9.1.tar.gz 453824 BLAKE2B c79b5755d7bd45b8ac32038e25d7b5c0f12195413802a03f6cbcc2430c4cea36a208ff012036fb3cca500baaad03b5fd3c084b5737e6e6866f3a0521d809f0e3 SHA512 cca3e713631bb3bc37012914c178dff1b1f54c79638182491c17030e510619200972cd9d4d6c03b5c246029a9bd2a0760a29ac951bcc2d8c2081328e560bbdcb
+EBUILD kodi-pvr-iptvsimple-20.9.1.ebuild 644 BLAKE2B c4c4adf418f5940362015d07725c32a1be93eac3af738e7b313d2c55aba786899290b731c996925ea6a608d12c0b1b1409789c2fdb0b1e6a09cf2b4f03d7048a SHA512 71ce6830ef544c2e5984190d05037b72e672ea22160fa0009ce095d146e0a34be36f2ebb3550e83606572b5754410a3861177b5e95d59add40c33878bfcd7755

media-plugins/kodi-pvr-iptvsimple/kodi-pvr-iptvsimple-20.9.1.ebuild

@@ -0,0 +1,35 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake kodi-addon
+
+DESCRIPTION="Kodi's IPTVSimple client addon"
+HOMEPAGE="https://github.com/kodi-pvr/pvr.iptvsimple"
+SRC_URI=""
+
+
+CODENAME="Nexus"
+KEYWORDS="~amd64 ~x86"
+SRC_URI="https://github.com/kodi-pvr/pvr.iptvsimple/archive/${PV}-${CODENAME}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/pvr.iptvsimple-${PV}-${CODENAME}"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+DEPEND="
+	dev-libs/pugixml
+	=media-tv/kodi-20*
+	sys-libs/zlib
+	"
+
+RDEPEND="
+	${DEPEND}
+	"
+
+src_prepare() {
+	[ -d depends ] && rm -rf depends || die
+	cmake_src_prepare
+}

media-plugins/kodi-vfs-sftp/Manifest

@@ -1,2 +1,2 @@
-DIST kodi-vfs-sftp-19.0.0.tar.gz 37670 BLAKE2B 53cdf37a7c36a96f76eb890218d5875d9dedb61b64adde9b8970a0669fbc2926c1f76d7abeb6326a96e3db4e9478e8de525bbbf6d8d0888db7680a46a4f780c0 SHA512 ead94ef065a49020d30243875239e088375870f2c70c19ac9b17894197ac793f1eec0fbf4c455ab9aa471dd660904c923f8820f875bdbe0f00b290ebccb43d77
+DIST kodi-vfs-sftp-20.1.0.tar.gz 45904 BLAKE2B f9c0f4359075609122627fbec2c945d643a844d7cb07eb09d7ab1581856a2c46790a36398e414ba9ef03c4b36eb361f2ea5a5a23aef980a83a8e6124e1b19f52 SHA512 ea2b205a5b4f279f8211a5744d0f5e6efb6346052ba927aef95733e1c964df5b97fc1176e2fa5d2b378561464f868cdc37e564ca120079f6ff70d2e79b48667c
-EBUILD kodi-vfs-sftp-19.0.0.ebuild 586 BLAKE2B 7bbba3668a70853221faec92888c247d97a9a9ee3bcf07f7465de8f1009ba71475da3e8b45372959ef103ea5b1a40c5dc35626ac4437f461a54d9a185b82c9f2 SHA512 8db34e5b84150c63864c514efe9b0f07b1ad5fa3aa8ca42b86b5b323c19538025637d4666f8c12c8840f12ea68f3d5942d54c98d8a9cf640fe6654ef3880c524
+EBUILD kodi-vfs-sftp-20.1.0.ebuild 595 BLAKE2B 2e88a24da83d7c9fd979f1b4abad4bdf177896fe45dcc86ccbbb2ae61d203f7902680f562ee0c585da3ece5db1f451bd9637c51451a907892623cc69cc73170f SHA512 15c96954c820040fed4d27e6449c264fc21eeb06342f68ba1ccdbf9662ff06a9747d23e34595888a856d307a75b23b8e8d18a21c08d7523be4ac48b6434f6293

media-plugins/kodi-vfs-sftp/kodi-vfs-sftp-20.1.0.ebuild

@@ -5,25 +5,25 @@ EAPI=7
 
 inherit cmake kodi-addon
 
-CODENAME="Matrix"
-
 DESCRIPTION="SFTP VFS addon for Kodi"
 HOMEPAGE="https://github.com/xbmc/vfs.sftp"
+SRC_URI=""
+
+CODENAME="Nexus"
+KEYWORDS="~amd64 ~x86"
 SRC_URI="https://github.com/xbmc/vfs.sftp/archive/${PV}-${CODENAME}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/vfs.sftp-${PV}-${CODENAME}"
 
 LICENSE="GPL-2"
 SLOT="0"
 IUSE=""
-KEYWORDS="~amd64 ~x86"
 
 DEPEND="
 	net-libs/libssh[sftp]
-	=media-tv/kodi-19*
+	=media-tv/kodi-20*
 	"
 RDEPEND="${DEPEND}"
 
-S="${WORKDIR}/vfs.sftp-${PV}-${CODENAME}"
-
 src_prepare() {
 	[ -d depends ] && rm -rf depends || die
 	cmake_src_prepare

media-tv/kodi/Manifest

@@ -0,0 +1,6 @@
+DIST ffmpeg-kodi-4.4.1-Nexus-Alpha1.tar.gz 13725564 BLAKE2B 51d310e7000aeba657d55341c5fdb540474e197b85062228ab4b314c8309ec11985aa7f105193333fc6106529e8e58c86eafe268190894be8532d0e0b9065fa6 SHA512 8beb04d577b5251e74b0d52f4d130997a8ba94bbd488c7c8309e6b45095c27807e150212888ce3a384b23dff52f8df1a7bde5407bae924ddc363f8125c0616c5
+DIST kodi-20.1-Nexus.tar.gz 54584529 BLAKE2B 32c945d7dbdcbfed4f319a91f445b6fd49de7fdcd59b2269aea46d7bc6b52677938800dbe9fba86e6e0451d86bb3afc80be6dd4f6f2fb83f6b2e3eb7375e2f8b SHA512 648df0649a0443d884b9414f43be4253764f1aaf9072aa8111e5a8a217c8291024ce1f27c2f7f673ac24005b32cc7dd25d86e99fc68166e3d5a637ae36b20f02
+DIST libdvdcss-1.4.3-Next-Nexus-Alpha2-2.tar.gz 102124 BLAKE2B 2f503d3ab767094958f7ec10b4ad11ffd02665deee571c8f3c739bef5fc7e2ff84babc5a3fdee638dc095f896b72fe3ce65e6b688674cb5f7b7b77190992688c SHA512 d3be3bfc13c5ea56d8db745c2aab090c99760684fe4c8f62a13d266feb319e9180ceeecf8116bfd2ed90d9accba2c11dbbf93b61ad00f69a40812ebf4eabcdda
+DIST libdvdnav-6.1.1-Next-Nexus-Alpha2-2.tar.gz 128547 BLAKE2B db4d05836d8fbb3637ae50bdbfc0e4b612ee6b3be24addfea94ce772c3bf28d58b63a3f252d6f9f016f72f8cbb841cc1820b091226b136f4c4664385a32da73c SHA512 51e6fc033121241354a5f0b3fc9a430577ae3ff6bb7f31445aa548ef4893037fb80eea3b2c6774c81e9ebaf9c45e9b490c98c2c65eb38f9f7daba84b236f7e1d
+DIST libdvdread-6.1.3-Next-Nexus-Alpha2-2.tar.gz 110513 BLAKE2B c94feb5a03a12efa5b7767965118d2500a088299ea36f3b82e46d157e45893e6b04503cb50f179ca681bac914457607fab26acfa6e304752b355c407578572d1 SHA512 629a41157d07b8ec0ea1fe89ae5ec48f63047472a862782b805c531ae31a0376fc4dc15175f8280c3ef91d7fa977bacebb1b51232640034a34bab2293210fc5e
+EBUILD kodi-20.1.ebuild 10892 BLAKE2B b8f0cf7d1352ecc2ca47af4b1b846ef27183d2695845c0897ef0f7dfcf6bfdd7b72f35361cac90b6dc354a25166dfd51aec7aaa3fdd9b48cb4a065bbb0db04e9 SHA512 f33299cd7c1748c17ee820115c0480babf92bbe777ba9b627bdfa50daefe3a0fdebf6946880a6e64588e4ef8f81f520bde793205bae89c1882087bcde91b81de

media-tv/kodi/kodi-20.1.ebuild

@@ -0,0 +1,359 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_REQ_USE="sqlite,ssl"
+LIBDVDCSS_VERSION="1.4.3-Next-Nexus-Alpha2-2"
+LIBDVDREAD_VERSION="6.1.3-Next-Nexus-Alpha2-2"
+LIBDVDNAV_VERSION="6.1.1-Next-Nexus-Alpha2-2"
+FFMPEG_VERSION="4.4.1"
+CODENAME="Nexus"
+FFMPEG_KODI_VERSION="Alpha1"
+PYTHON_COMPAT=( python3_{10,11} )
+SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz -> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz
+	https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz -> libdvdread-${LIBDVDREAD_VERSION}.tar.gz
+	https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz -> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz
+	!system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )"
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
+	EGIT_BRANCH="Matrix"
+	inherit git-r3
+else
+	MY_PV=${PV/_p/_r}
+	MY_PV=${MY_PV/_alpha/a}
+	MY_PV=${MY_PV/_beta/b}
+	MY_PV=${MY_PV/_rc/RC}
+	MY_PV="${MY_PV}-${CODENAME}"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+	S=${WORKDIR}/xbmc-${MY_PV}
+fi
+
+inherit autotools cmake desktop libtool linux-info pax-utils python-single-r1 xdg
+
+DESCRIPTION="A free and open source media-player and entertainment hub"
+HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+# use flag is called libusb so that it doesn't fool people in thinking that
+# it is _required_ for USB support. Otherwise they'll disable udev and
+# that's going to be worse.
+IUSE="airplay alsa bluetooth bluray caps cec +css dav1d dbus eventclients gbm gles lcms libusb lirc mariadb mysql nfs +optical pipewire power-control pulseaudio raspberry-pi samba +system-ffmpeg test udf udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf"
+IUSE="${IUSE} cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_arm_neon"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	|| ( gbm wayland X )
+	?? ( mariadb mysql )
+	bluray? ( udf )
+	udev? ( !libusb )
+	udisks? ( dbus )
+	upower? ( dbus )
+	power-control? ( dbus )
+	vdpau? (
+		X
+		!gles
+		!gbm
+	)
+	zeroconf? ( dbus )
+"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	>=dev-libs/lzo-2.04
+	>=dev-libs/flatbuffers-1.12.0:=
+	>=media-libs/libjpeg-turbo-2.0.4:=
+	>=media-libs/libpng-1.6.26:0=
+"
+COMMON_TARGET_DEPEND="${PYTHON_DEPS}
+	airplay? (
+		>=app-pda/libplist-2.0.0
+		net-libs/shairplay
+	)
+	alsa? ( >=media-libs/alsa-lib-1.1.4.1 )
+	bluetooth? ( net-wireless/bluez )
+	bluray? ( >=media-libs/libbluray-1.1.2 )
+	caps? ( sys-libs/libcap )
+	dbus? ( sys-apps/dbus )
+	dev-db/sqlite
+	dev-libs/crossguid
+	>=dev-libs/fribidi-1.0.5
+	cec? ( >=dev-libs/libcec-4.0[raspberry-pi?] )
+	dev-libs/libpcre[cxx]
+	>=dev-libs/spdlog-1.5.0:=
+	dev-libs/tinyxml[stl]
+	$(python_gen_cond_dep '
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+	')
+	>=dev-libs/libcdio-2.1.0[cxx]
+	>=dev-libs/libfmt-6.1.2
+	dev-libs/libfstrcmp
+	gbm? (
+		>=dev-libs/libinput-1.10.5
+		media-libs/mesa[gbm(+)]
+		x11-libs/libxkbcommon
+	)
+	gles? (
+		!raspberry-pi? ( media-libs/mesa[gles2] )
+	)
+	lcms? ( media-libs/lcms:2 )
+	libusb? ( virtual/libusb:1 )
+	virtual/ttf-fonts
+	media-fonts/roboto
+	>=media-libs/freetype-2.10.1
+	>=media-libs/libass-0.13.4
+	!raspberry-pi? ( media-libs/mesa[egl(+)] )
+	>=media-libs/taglib-1.11.1
+	system-ffmpeg? (
+		>=media-video/ffmpeg-${FFMPEG_VERSION}:=[dav1d?,encode,postproc]
+		=media-video/ffmpeg-4*[openssl]
+	)
+	!system-ffmpeg? (
+		app-arch/bzip2
+		dav1d? ( media-libs/dav1d:= )
+	)
+	mysql? ( dev-db/mysql-connector-c:= )
+	mariadb? ( dev-db/mariadb-connector-c:= )
+	>=net-misc/curl-7.68.0[http2]
+	nfs? ( >=net-fs/libnfs-2.0.0:= )
+	!gles? ( media-libs/glu )
+	>=dev-libs/openssl-1.1.1k:0=
+	raspberry-pi? (
+		|| ( media-libs/raspberrypi-userland media-libs/raspberrypi-userland-bin media-libs/mesa[egl(+),gles2,video_cards_vc4] )
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
+	>=sys-libs/zlib-1.2.11
+	udf? ( >=dev-libs/libudfread-1.0.0 )
+	udev? ( virtual/udev )
+	vaapi? (
+		media-libs/libva:=
+		system-ffmpeg? ( media-video/ffmpeg[vaapi] )
+		wayland? ( media-libs/libva[wayland] )
+		X? ( media-libs/libva[X] )
+	)
+	virtual/libiconv
+	vdpau? (
+		|| ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
+		system-ffmpeg? ( media-video/ffmpeg[vdpau] )
+	)
+	wayland? (
+		>=dev-cpp/waylandpp-0.2.3:=
+		media-libs/mesa[wayland]
+		>=dev-libs/wayland-protocols-1.7
+		>=x11-libs/libxkbcommon-0.4.1
+	)
+	webserver? ( >=net-libs/libmicrohttpd-0.9.55[messages(+)] )
+	X? (
+		media-libs/mesa[X]
+		!gles? ( media-libs/libglvnd[X] )
+		x11-libs/libX11
+		x11-libs/libXrandr
+		x11-libs/libXrender
+		system-ffmpeg? ( media-video/ffmpeg[X] )
+	)
+	x11-libs/libdrm
+	xslt? (
+		dev-libs/libxslt
+		>=dev-libs/libxml2-2.9.4
+	)
+	zeroconf? ( net-dns/avahi[dbus] )
+"
+RDEPEND="${COMMON_DEPEND} ${COMMON_TARGET_DEPEND}
+	lirc? ( app-misc/lirc )
+	power-control? ( || ( sys-apps/systemd sys-auth/elogind ) )
+	udisks? ( sys-fs/udisks:2 )
+	upower? ( sys-power/upower )
+"
+DEPEND="${COMMON_DEPEND} ${COMMON_TARGET_DEPEND}
+	dev-libs/rapidjson
+	test? ( >=dev-cpp/gtest-1.10.0 )
+"
+BDEPEND="${COMMON_DEPEND}
+	dev-lang/swig
+	dev-util/cmake
+	media-libs/giflib
+	>=dev-libs/flatbuffers-1.11.0
+	>=media-libs/libjpeg-turbo-2.0.4:=
+	>=media-libs/libpng-1.6.26:0=
+	virtual/pkgconfig
+	virtual/jre
+"
+
+CONFIG_CHECK="~IP_MULTICAST"
+ERROR_IP_MULTICAST="
+In some cases Kodi needs to access multicast addresses.
+Please consider enabling IP_MULTICAST under Networking options.
+"
+
+pkg_setup() {
+	check_extra_config
+	python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999 ]] ; then
+		git-r3_src_unpack
+	else
+		default
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# avoid long delays when powerkit isn't running #348580
+	sed -i \
+		-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
+		xbmc/platform/linux/*.cpp || die
+
+	# Prepare tools and libs witch are configured with autotools during compile time
+	AUTOTOOLS_DIRS=(
+		"${S}"/tools/depends/native/TexturePacker/src
+		"${S}"/tools/depends/native/JsonSchemaBuilder/src
+	)
+
+	local d
+	for d in "${AUTOTOOLS_DIRS[@]}" ; do
+		pushd ${d} >/dev/null || die
+		AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
+		popd >/dev/null || die
+	done
+	elibtoolize
+
+	# Prevent autoreconf rerun
+	sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
+		"${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
+		"${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
+		|| die
+}
+
+src_configure() {
+	local platform=()
+	use gbm && platform+=( gbm )
+	use wayland && platform+=( wayland )
+	use X && platform+=( x11 )
+	local core_platform_name="${platform[@]}"
+	local mycmakeargs=(
+		-DENABLE_SSE=$(usex cpu_flags_x86_sse)
+		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
+		-DENABLE_SSE3=$(usex cpu_flags_x86_sse3)
+		-DENABLE_SSE4_1=$(usex cpu_flags_x86_sse4_1)
+		-DENABLE_SSE4_2=$(usex cpu_flags_x86_sse4_2)
+		-DENABLE_AVX=$(usex cpu_flags_x86_avx)
+		-DENABLE_AVX2=$(usex cpu_flags_x86_avx2)
+		-DENABLE_NEON=$(usex cpu_flags_arm_neon)
+		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+		-DVERBOSE=ON
+		-DENABLE_GOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
+		-DENABLE_ALSA=$(usex alsa)
+		-DENABLE_AIRTUNES=$(usex airplay)
+		-DENABLE_AVAHI=$(usex zeroconf)
+		-DENABLE_BLUETOOTH=$(usex bluetooth)
+		-DENABLE_BLURAY=$(usex bluray)
+		-DENABLE_CCACHE=OFF
+		-DENABLE_CLANGFORMAT=OFF
+		-DENABLE_CLANGTIDY=OFF
+		-DENABLE_CPPCHECK=OFF
+		-DENABLE_ISO9660PP=$(usex optical)
+		-DENABLE_CEC=$(usex cec)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DVDCSS=$(usex css)
+		-DENABLE_EVENTCLIENTS=ON # alway enable to have 'kodi-send' and filter extra staff in 'src_install()'
+		-DENABLE_INTERNAL_CROSSGUID=OFF
+		-DENABLE_INTERNAL_RapidJSON=OFF
+		-DENABLE_INTERNAL_FMT=OFF
+		-DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
+		-DENABLE_INTERNAL_FSTRCMP=OFF
+		-DENABLE_INTERNAL_FLATBUFFERS=OFF
+		-DENABLE_INTERNAL_DAV1D=OFF
+		-DENABLE_INTERNAL_GTEST=OFF
+		-DENABLE_INTERNAL_UDFREAD=OFF
+		-DENABLE_INTERNAL_SPDLOG=OFF
+		-DENABLE_CAP=$(usex caps)
+		-DENABLE_LCMS2=$(usex lcms)
+		-DENABLE_LIRCCLIENT=$(usex lirc)
+		-DENABLE_MARIADBCLIENT=$(usex mariadb)
+		-DENABLE_MDNS=OFF # used only on Android
+		-DENABLE_MICROHTTPD=$(usex webserver)
+		-DENABLE_MYSQLCLIENT=$(usex mysql)
+		-DENABLE_NFS=$(usex nfs)
+		-DENABLE_OPENGLES=$(usex gles)
+		-DENABLE_OPENGL=$(usex !gles)
+		-DENABLE_OPTICAL=$(usex optical)
+		-DENABLE_PLIST=$(usex airplay)
+		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
+		-DENABLE_SMBCLIENT=$(usex samba)
+		-DENABLE_SNDIO=OFF
+		-DENABLE_TESTING=$(usex test)
+		-DENABLE_UDEV=$(usex udev)
+		-DENABLE_UDFREAD=$(usex udf)
+		-DENABLE_UPNP=$(usex upnp)
+		-DENABLE_VAAPI=$(usex vaapi)
+		-DENABLE_VDPAU=$(usex vdpau)
+		-DENABLE_XSLT=$(usex xslt)
+		-Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz"
+		-Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_VERSION}.tar.gz"
+		-Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz"
+		-DPYTHON_PATH="$(python_get_library_path)"
+		-DAPP_RENDER_SYSTEM="$(usex gles gles gl)"
+		-DCORE_PLATFORM_NAME="${core_platform_name}"
+	)
+
+	use !udev && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
+
+	use X && use !gles && mycmakeargs+=( -DENABLE_GLX=ON )
+
+	if use system-ffmpeg; then
+		mycmakeargs+=( -DWITH_FFMPEG="yes" )
+	else
+		mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
+	fi
+
+	if ! echo "${CFLAGS}" | grep -Fwqe '-DNDEBUG' - && ! echo "${CFLAGS}" | grep -Fwqe '-D_DEBUG' - ; then
+		CFLAGS+=' -DNDEBUG' # Kodi requires one of the 'NDEBUG' or '_DEBUG' defines
+		CXXFLAGS+=' -DNDEBUG'
+	fi
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile all
+}
+
+src_test() {
+	local myctestargs=(
+		# Known failing, unreliable test
+		# bug #743938
+		-E "(TestCPUInfo.GetCPUFrequency)"
+	)
+
+	# see https://github.com/xbmc/xbmc/issues/17860#issuecomment-630120213
+	KODI_HOME="${BUILD_DIR}" cmake_build check
+}
+
+src_install() {
+	cmake_src_install
+
+	pax-mark Em "${ED}"/usr/$(get_libdir)/${PN}/${PN}.bin
+
+	newicon media/icon48x48.png kodi.png
+
+	rm "${ED}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
+	dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
+		usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
+
+	if use !eventclients ; then
+		rm -f "${ED}"/usr/bin/kodi-ps3remote || die
+		rm -f "${D}"$(python_get_sitedir)/kodi/ps3_remote.py || die
+		rm -rf "${D}"$(python_get_sitedir)/kodi/ps3 || die
+		rm -rf "${D}"$(python_get_sitedir)/kodi/bt || die
+		rm -rf "${ED}"/usr/share/doc/${PF}/kodi-eventclients-dev || die
+	fi
+
+	python_optimize "${D}$(python_get_sitedir)"
+}